let
    //Get list of files in folder
    Source = Folder.Files("C:\Image Folder"),
    #"Filtered Rows" = Table.SelectRows(Source, each ([Extension] = ".png")),
    #"Replaced Value" = Table.ReplaceValue(#"Filtered Rows",".png","",Replacer.ReplaceText,{"Name"}),
    //Remove unnecessary columns
    RemoveOtherColumns = Table.SelectColumns(#"Replaced Value",{"Content", "Name"}),
    //Creates Splitter function
    SplitTextFunction = Splitter.SplitTextByRepeatedLengths(30000),
    //Converts table of files to list
    ListInput = Table.ToRows(RemoveOtherColumns),
    //Function to convert binary of photo to multiple
    //text values
    ConvertOneFile = (InputRow as list) =>
        let
            BinaryIn = InputRow{0},
            FileName = InputRow{1},
            BinaryText = Binary.ToText(BinaryIn, BinaryEncoding.Base64),
            SplitUpText = SplitTextFunction(BinaryText),
            AddPartIndex = List.Zip({SplitUpText, List.Positions(SplitUpText)}),
            AddFileName = List.Transform(AddPartIndex, each {FileName} & _ )
        in
            AddFileName,
    //Loops over all photos and calls the above function
    ConvertAllFiles = List.Transform(ListInput, each ConvertOneFile(_)),
    //Combines lists together
    CombineLists = List.Combine(ConvertAllFiles),
    //Converts results to table
    ToTable = #table(type table[Name=text,Index=Int64.Type,Image=text],CombineLists)
in
    ToTable